压电悬臂梁谐振频率及反谐振频率问题求助（附APDL）

qshcjn1

最近在做压电悬臂梁的时候遇到了一些问题。我需要求机电耦合系数，查找了资料之后发现有的资料上写的公式用到了谐振频率和反谐振频率，还有的资料上提到的是压电片开路和短路时梁的固有频率，我认为这两种说法表达的是一样的东西，不知道对不对？

在APDL中我将压电片粘贴在悬臂梁上，然后试图“给压电片上下表面都加0V电压”（短路）和“只给压电片下表面加0V电压”（开路），然后分别作模态分析，以求出压电片短路和开路条件下，悬臂梁的固有频率。但是模态分析的结果是，两种情况下悬臂梁各阶固有频率完全相等，不知道到底是哪里错了，希望高手指点。

下附APDL：

/PREP7     !模态分析
ET,1,SOLID226,1001   !定义压电陶瓷元素类型
ET,2,45     !定义悬臂梁元素类型
MP,DENS,1,7700    !定义压电陶瓷材料密度
TB,DPER,1    !定义压电陶瓷介电常数矩阵
TBDATA,1,729,635,729
TB,ANEL,1    !定义压电陶瓷刚度矩阵
TBDATA,1,13.9E10,7.43E10,7.78E10
TBDATA,7,11.5E10,7.43E10
TBDATA,12,13.9E10
TBDATA,16,2.56E10
TBDATA,19,2.56E10
TBDATA,21,3.06E10
TB,PIEZ,1    !定义压电陶瓷应力矩阵
TBDATA,2,-5.2
TBDATA,5,15.1
TBDATA,8,-5.2
TBDATA,10,12.7
TBDATA,15,12.7
MP,DENS,3,8200    !定义悬臂梁材料密度
MP,EX,3,1.17E11    !定义悬臂梁材料弹性模量
MP,PRXY,3,0.3    !定义悬臂梁材料泊松比
*SET,Lb,200E-03    !设置各元素宽、厚、长度
*SET,b,15E-3
*SET,L1,10E-3
*SET,L2,35E-3
*SET,hb,1.2E-3
*SET,hp,0.2E-3
NUMSTR,node,14
BLOCK,0,Lb,-b/2,b/2,0,hb  !建立悬臂梁实体
BLOCK,L1,L2,-b/2,b/2,hb,hb+hp  !建立压电陶瓷实体
ALLSEL,ALL
VGLUE,ALL    !将压电陶瓷和悬臂梁进行粘贴
ALLSEL,ALL
LSEL,S,LOC,X,L1,L2
LESIZE,ALL,1E-3, , , , , , ,1  !给压电陶瓷划分网格
LSEL,INVE
LESIZE,ALL,1E-3, , , , , , ,1  !给悬臂梁划分网格
ALLSEL,ALL
VSEL,S,LOC,Z,hb,hb+hp
TYPE,1     !给压电陶瓷定义元素及材料类型
MAT,1
VPLOT
VSWEEP,ALL
VSEL,INVE
TYPE,2     !给悬臂梁定义元素及材料类型
MAT,3
VPLOT
VSWEEP,ALL
ALLSEL,ALL
ASEL,S,LOC,Z,hb
ASEL,R,LOC,X,L1,L2
NSLA,R,1
CP,1,VOLT,ALL    !定义底部电极
*GET,n_bot,NODE,0,num,min
ALLSEL,ALL
ASEL,S,LOC,Z,hb+hp
NSLA,R,1
CP,2,VOLT,ALL    !定义顶部电极
*GET,n_top,NODE,0,num,min
ALLSEL,ALL
ASEL,S,LOC,X,0
DA,ALL,UX,0
DA,ALL,UY,0
DA,ALL,UZ,0
ALLSEL,ALL
D,n_bot,VOLT,0    !定义相关自由度
FINISH

/SOL     !压电陶瓷开路
ANTYPE,MODAL    !模态分析
*SET,nmodes,4    !设定模态数
MODOPT,LANB,nmodes
MXPAND,nmodes,,,YES
SOLVE
FINISH

/POST1     !后处理
*DIM,Fo,ARRAY,nmodes   !定义数组储存开路固有频率
SET,FIRST    !设定初始为一阶
*DO,i,1,nmodes    !进入循环，从一阶模态开始
*GET,Fo(i),mode,i,freq  !获取i阶开路固有频率Fo(i)
SET,NEXT   !设置为下一阶模态
*ENDDO
FINISH

/SOL     !压电陶瓷短路
ANTYPE,MODAL    !模态分析
*SET,nmodes,4    !设定模态数
MODOPT,LANB,nmodes
MXPAND,nmodes,,,YES
D,n_top,VOLT,0    !将顶部电极短路
SOLVE
FINISH

/POST1     !后处理
*DIM,Fs,ARRAY,nmodes   !定义数组储存短路固有频率
SET,FIRST    !设定初始为一阶
*DO,i,1,nmodes    !进入循环，从一阶模态开始
*GET,Fs(i),mode,i,freq  !获取i阶短路固有频率Fs(i)
SET,NEXT   !设置为下一阶模态
*ENDDO
FINISH

onattacking

开路时没有删除已经施加的电压，我也作这个东西，可以互相学习啊

flyuf

我也很想知道

狼毒花

请详细指点一下啊，